Gecko [ www.utparral.edu.mx ]

Name	Size	Permission
appdata-xml.m4	3.11 KB	-rw-r--r--
appstream-xml.m4	2.94 KB	-rw-r--r--
expat.m4	1.41 KB	-rw-r--r--
gettext.m4	14.15 KB	-rw-r--r--
glib-2.0.m4	8.17 KB	-rw-r--r--
glib-gettext.m4	15.38 KB	-rw-r--r--
gpg-error.m4	7.98 KB	-rw-r--r--
gpgrt.m4	3.99 KB	-rw-r--r--
gsettings.m4	3.5 KB	-rw-r--r--
gtk-3.0.m4	8.03 KB	-rw-r--r--
host-cpu-c-abi.m4	21.91 KB	-rw-r--r--
iconv.m4	9.5 KB	-rw-r--r--
intlmacosx.m4	3.15 KB	-rw-r--r--
introspection.m4	5.01 KB	-rw-r--r--
libcurl.m4	10.91 KB	-rw-r--r--
libgcrypt.m4	6.1 KB	-rw-r--r--
lib-ld.m4	5.24 KB	-rw-r--r--
lib-link.m4	33.99 KB	-rw-r--r--
lib-prefix.m4	11.66 KB	-rw-r--r--
libtool.m4	299.49 KB	-rw-r--r--
libxml2.m4	7.72 KB	-rw-r--r--
ltargz.m4	2.51 KB	-rw-r--r--
ltdl.m4	29.34 KB	-rw-r--r--
lt~obsolete.m4	6 KB	-rw-r--r--
ltoptions.m4	14.17 KB	-rw-r--r--
ltsugar.m4	4.28 KB	-rw-r--r--
ltversion.m4	699 B	-rw-r--r--
mm-ax_cxx_compile_stdcxx_11.m4	5.66 KB	-rw-r--r--
mm-ax_cxx_compile_stdcxx.m4	19.1 KB	-rw-r--r--
mm-common.m4	1.64 KB	-rw-r--r--
mm-dietlib.m4	4.57 KB	-rw-r--r--
mm-doc.m4	10.27 KB	-rw-r--r--
mm-module.m4	3.25 KB	-rw-r--r--
mm-pkg.m4	3.87 KB	-rw-r--r--
mm-warnings.m4	4.56 KB	-rw-r--r--
nls.m4	1.21 KB	-rw-r--r--
nspr.m4	2.76 KB	-rw-r--r--
pkg.m4	10.01 KB	-rw-r--r--
po.m4	18.39 KB	-rw-r--r--
progtest.m4	3.02 KB	-rw-r--r--
vala.m4	4.46 KB	-rw-r--r--
vapigen.m4	3.4 KB	-rw-r--r--
wayland-scanner.m4	428 B	-rw-r--r--
xtrans.m4	6.38 KB	-rw-r--r--

Code Editor : vapigen.m4

dnl vapigen.m4
dnl
dnl Copyright 2012 Evan Nemerson
dnl
dnl This library is free software; you can redistribute it and/or
dnl modify it under the terms of the GNU Lesser General Public
dnl License as published by the Free Software Foundation; either
dnl version 2.1 of the License, or (at your option) any later version.
dnl
dnl This library is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl Lesser General Public License for more details.
dnl
dnl You should have received a copy of the GNU Lesser General Public
dnl License along with this library; if not, write to the Free Software
dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA

# VAPIGEN_CHECK([VERSION], [API_VERSION], [FOUND_INTROSPECTION], [DEFAULT])
# --------------------------------------
# Check vapigen existence and version
#
# See http://live.gnome.org/Vala/UpstreamGuide for detailed documentation
AC_DEFUN([VAPIGEN_CHECK],
[
  AS_IF([test "x$3" != "xyes"], [
      m4_provide_if([GOBJECT_INTROSPECTION_CHECK], [], [
          m4_provide_if([GOBJECT_INTROSPECTION_REQUIRE], [], [
              AC_MSG_ERROR([[You must call GOBJECT_INTROSPECTION_CHECK or GOBJECT_INTROSPECTION_REQUIRE before using VAPIGEN_CHECK unless using the FOUND_INTROSPECTION argument is "yes"]])
            ])
        ])
    ])

AC_ARG_ENABLE([vala],
    [AS_HELP_STRING([--enable-vala[=@<:@no/auto/yes@:>@]],[build Vala bindings @<:@default=]ifelse($4,,auto,$4)[@:>@])],,[
      AS_IF([test "x$4" = "x"], [
          enable_vala=auto
        ], [
          enable_vala=$4
        ])
    ])

AS_CASE([$enable_vala], [no], [enable_vala=no],
      [yes], [
        AS_IF([test "x$3" != "xyes" -a "x$found_introspection" != "xyes"], [
            AC_MSG_ERROR([Vala bindings require GObject Introspection])
          ])
      ], [auto], [
        AS_IF([test "x$3" != "xyes" -a "x$found_introspection" != "xyes"], [
            enable_vala=no
          ])
      ], [
        AC_MSG_ERROR([Invalid argument passed to --enable-vala, should be one of @<:@no/auto/yes@:>@])
      ])

AS_IF([test "x$2" = "x"], [
      vapigen_pkg_name=vapigen
    ], [
      vapigen_pkg_name=vapigen-$2
    ])
  AS_IF([test "x$1" = "x"], [
      vapigen_pkg="$vapigen_pkg_name"
    ], [
      vapigen_pkg="$vapigen_pkg_name >= $1"
    ])

PKG_PROG_PKG_CONFIG

PKG_CHECK_EXISTS([$vapigen_pkg], [
      AS_IF([test "$enable_vala" = "auto"], [
          enable_vala=yes
        ])
    ], [
      AS_CASE([$enable_vala], [yes], [
          AC_MSG_ERROR([$vapigen_pkg not found])
        ], [auto], [
          enable_vala=no
        ])
    ])

AC_MSG_CHECKING([for vapigen])

AS_CASE([$enable_vala],
    [yes], [
      VAPIGEN=$PKG_CONFIG_SYSROOT_DIR`$PKG_CONFIG --variable=vapigen $vapigen_pkg_name`
      VAPIGEN_MAKEFILE=$PKG_CONFIG_SYSROOT_DIR`$PKG_CONFIG --variable=datadir $vapigen_pkg_name`/vala/Makefile.vapigen
      AS_IF([test "x$2" = "x"], [
          VAPIGEN_VAPIDIR=$PKG_CONFIG_SYSROOT_DIR`$PKG_CONFIG --variable=vapidir $vapigen_pkg_name`
        ], [
          VAPIGEN_VAPIDIR=$PKG_CONFIG_SYSROOT_DIR`$PKG_CONFIG --variable=vapidir_versioned $vapigen_pkg_name`
        ])
    ])

AC_MSG_RESULT([$enable_vala])

AC_SUBST([VAPIGEN])
  AC_SUBST([VAPIGEN_VAPIDIR])
  AC_SUBST([VAPIGEN_MAKEFILE])

AM_CONDITIONAL(ENABLE_VAPIGEN, test "x$enable_vala" = "xyes")
])

${this.title}

Code Editor : vapigen.m4