Gecko [ www.utparral.edu.mx ]

Name	Size	Permission
appdata-xml.m4	3.11 KB	-rw-r--r--
appstream-xml.m4	2.94 KB	-rw-r--r--
expat.m4	1.41 KB	-rw-r--r--
gettext.m4	14.15 KB	-rw-r--r--
glib-2.0.m4	8.17 KB	-rw-r--r--
glib-gettext.m4	15.38 KB	-rw-r--r--
gpg-error.m4	7.98 KB	-rw-r--r--
gpgrt.m4	3.99 KB	-rw-r--r--
gsettings.m4	3.5 KB	-rw-r--r--
gtk-3.0.m4	8.03 KB	-rw-r--r--
host-cpu-c-abi.m4	21.91 KB	-rw-r--r--
iconv.m4	9.5 KB	-rw-r--r--
intlmacosx.m4	3.15 KB	-rw-r--r--
introspection.m4	5.01 KB	-rw-r--r--
libcurl.m4	10.91 KB	-rw-r--r--
libgcrypt.m4	6.1 KB	-rw-r--r--
lib-ld.m4	5.24 KB	-rw-r--r--
lib-link.m4	33.99 KB	-rw-r--r--
lib-prefix.m4	11.66 KB	-rw-r--r--
libtool.m4	299.49 KB	-rw-r--r--
libxml2.m4	7.72 KB	-rw-r--r--
ltargz.m4	2.51 KB	-rw-r--r--
ltdl.m4	29.34 KB	-rw-r--r--
lt~obsolete.m4	6 KB	-rw-r--r--
ltoptions.m4	14.17 KB	-rw-r--r--
ltsugar.m4	4.28 KB	-rw-r--r--
ltversion.m4	699 B	-rw-r--r--
mm-ax_cxx_compile_stdcxx_11.m4	5.66 KB	-rw-r--r--
mm-ax_cxx_compile_stdcxx.m4	19.1 KB	-rw-r--r--
mm-common.m4	1.64 KB	-rw-r--r--
mm-dietlib.m4	4.57 KB	-rw-r--r--
mm-doc.m4	10.27 KB	-rw-r--r--
mm-module.m4	3.25 KB	-rw-r--r--
mm-pkg.m4	3.87 KB	-rw-r--r--
mm-warnings.m4	4.56 KB	-rw-r--r--
nls.m4	1.21 KB	-rw-r--r--
nspr.m4	2.76 KB	-rw-r--r--
pkg.m4	10.01 KB	-rw-r--r--
po.m4	18.39 KB	-rw-r--r--
progtest.m4	3.02 KB	-rw-r--r--
vala.m4	4.46 KB	-rw-r--r--
vapigen.m4	3.4 KB	-rw-r--r--
wayland-scanner.m4	428 B	-rw-r--r--
xtrans.m4	6.38 KB	-rw-r--r--

Code Editor : mm-ax_cxx_compile_stdcxx_11.m4

# ============================================================================
#  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html
# ============================================================================
#
# SYNOPSIS
#
#   MM_AX_CXX_COMPILE_STDCXX_11([ext|noext],[mandatory|optional])
#
# DESCRIPTION
#
#   Check for baseline language coverage in the compiler for the C++11
#   standard; if necessary, add switches to CXXFLAGS to enable support.
#
#   The first argument, if specified, indicates whether you insist on an
#   extended mode (e.g. -std=gnu++11) or a strict conformance mode (e.g.
#   -std=c++11).  If neither is specified, you get whatever works, with
#   preference for an extended mode.
#
#   The second argument, if specified 'mandatory' or if left unspecified,
#   indicates that baseline C++11 support is required and that the macro
#   should error out if no mode with that support is found.  If specified
#   'optional', then configuration proceeds regardless, after defining
#   HAVE_CXX11 if and only if a supporting mode is found.
#
# LICENSE
#
#   Copyright (c) 2008 Benjamin Kosnik <bkoz@redhat.com>
#   Copyright (c) 2012 Zack Weinberg <zackw@panix.com>
#   Copyright (c) 2013 Roy Stogner <roystgnr@ices.utexas.edu>
#   Copyright (c) 2014, 2015 Google Inc.; contributed by Alexey Sokolov <sokolov@google.com>
#
#   Copying and distribution of this file, with or without modification, are
#   permitted in any medium without royalty provided the copyright notice
#   and this notice are preserved. This file is offered as-is, without any
#   warranty.

# Copied from ax_cxx_compile_stdcxx_11.m4 and added MM_ prefix to avoid
# possible conflict with AX_CXX_COMPILE_STDCXX_11 in other modules.

#serial 11

m4_define([_MM_AX_CXX_COMPILE_STDCXX_11_testbody], [[
  template <typename T>
    struct check
    {
      static_assert(sizeof(int) <= sizeof(T), "not big enough");
    };

struct Base {
    virtual void f() {}
    };
    struct Child : public Base {
    virtual void f() override {}
    };

typedef check<check<bool>> right_angle_brackets;

int a;
    decltype(a) b;

typedef check<int> check_type;
    check_type c;
    check_type&& cr = static_cast<check_type&&>(c);

auto d = a;
    auto l = [](){};
    // Prevent Clang error: unused variable 'l' [-Werror,-Wunused-variable]
    struct use_l { use_l() { l(); } };

// http://stackoverflow.com/questions/13728184/template-aliases-and-sfinae
    // Clang 3.1 fails with headers of libstd++ 4.8.3 when using std::function because of this
    namespace test_template_alias_sfinae {
        struct foo {};

template<typename T>
        using member = typename T::member_type;

template<typename T>
        void func(...) {}

template<typename T>
        void func(member<T>*) {}

void test();

void test() {
            func<foo>(0);
        }
    }
]])

AC_DEFUN([MM_AX_CXX_COMPILE_STDCXX_11], [dnl
  m4_if([$1], [], [],
        [$1], [ext], [],
        [$1], [noext], [],
        [m4_fatal([invalid argument `$1' to MM_AX_CXX_COMPILE_STDCXX_11])])dnl
  m4_if([$2], [], [ax_cxx_compile_cxx11_required=true],
        [$2], [mandatory], [ax_cxx_compile_cxx11_required=true],
        [$2], [optional], [ax_cxx_compile_cxx11_required=false],
        [m4_fatal([invalid second argument `$2' to MM_AX_CXX_COMPILE_STDCXX_11])])
  AC_LANG_PUSH([C++])dnl
  ac_success=no
  AC_CACHE_CHECK(whether $CXX supports C++11 features by default,
  ax_cv_cxx_compile_cxx11,
  [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_MM_AX_CXX_COMPILE_STDCXX_11_testbody])],
    [ax_cv_cxx_compile_cxx11=yes],
    [ax_cv_cxx_compile_cxx11=no])])
  if test x$ax_cv_cxx_compile_cxx11 = xyes; then
    ac_success=yes
  fi

m4_if([$1], [noext], [], [dnl
  if test x$ac_success = xno; then
    for switch in -std=gnu++11 -std=gnu++0x; do
      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
                     $cachevar,
        [ac_save_CXXFLAGS="$CXXFLAGS"
         CXXFLAGS="$CXXFLAGS $switch"
         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_MM_AX_CXX_COMPILE_STDCXX_11_testbody])],
          [eval $cachevar=yes],
          [eval $cachevar=no])
         CXXFLAGS="$ac_save_CXXFLAGS"])
      if eval test x\$$cachevar = xyes; then
        CXXFLAGS="$CXXFLAGS $switch"
        ac_success=yes
        break
      fi
    done
  fi])

m4_if([$1], [ext], [], [dnl
  if test x$ac_success = xno; then
    dnl HP's aCC needs +std=c++11 according to:
    dnl http://h21007.www2.hp.com/portal/download/files/unprot/aCxx/PDF_Release_Notes/769149-001.pdf
    for switch in -std=c++11 -std=c++0x +std=c++11; do
      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
                     $cachevar,
        [ac_save_CXXFLAGS="$CXXFLAGS"
         CXXFLAGS="$CXXFLAGS $switch"
         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_MM_AX_CXX_COMPILE_STDCXX_11_testbody])],
          [eval $cachevar=yes],
          [eval $cachevar=no])
         CXXFLAGS="$ac_save_CXXFLAGS"])
      if eval test x\$$cachevar = xyes; then
        CXXFLAGS="$CXXFLAGS $switch"
        ac_success=yes
        break
      fi
    done
  fi])
  AC_LANG_POP([C++])
  if test x$ax_cxx_compile_cxx11_required = xtrue; then
    if test x$ac_success = xno; then
      AC_MSG_ERROR([*** A compiler with support for C++11 language features is required.])
    fi
  else
    if test x$ac_success = xno; then
      HAVE_CXX11=0
      AC_MSG_NOTICE([No compiler with C++11 support was found])
    else
      HAVE_CXX11=1
      AC_DEFINE(HAVE_CXX11,1,
                [define if the compiler supports basic C++11 syntax])
    fi

AC_SUBST(HAVE_CXX11)
  fi
])

${this.title}

Code Editor : mm-ax_cxx_compile_stdcxx_11.m4