Gecko [ www.utparral.edu.mx ]

Name	Size	Permission
file	[ DIR ]	drwxr-xr-x
urn	[ DIR ]	drwxr-xr-x
data.pm	3.26 KB	-r--r--r--
Escape.pm	6.45 KB	-r--r--r--
file.pm	9.63 KB	-r--r--r--
_foreign.pm	75 B	-r--r--r--
ftp.pm	1.03 KB	-r--r--r--
_generic.pm	5.53 KB	-r--r--r--
gopher.pm	2.34 KB	-r--r--r--
Heuristic.pm	5.57 KB	-r--r--r--
http.pm	405 B	-r--r--r--
https.pm	89 B	-r--r--r--
ldapi.pm	460 B	-r--r--r--
_ldap.pm	3.17 KB	-r--r--r--
ldap.pm	2.93 KB	-r--r--r--
ldaps.pm	89 B	-r--r--r--
_login.pm	222 B	-r--r--r--
mailto.pm	1.22 KB	-r--r--r--
mms.pm	89 B	-r--r--r--
news.pm	1.39 KB	-r--r--r--
nntp.pm	91 B	-r--r--r--
pop.pm	1.15 KB	-r--r--r--
QueryParam.pm	4.54 KB	-r--r--r--
_query.pm	2 KB	-r--r--r--
rlogin.pm	96 B	-r--r--r--
rsync.pm	197 B	-r--r--r--
rtsp.pm	89 B	-r--r--r--
rtspu.pm	90 B	-r--r--r--
_segment.pm	377 B	-r--r--r--
_server.pm	2.19 KB	-r--r--r--
sip.pm	1.71 KB	-r--r--r--
sips.pm	87 B	-r--r--r--
snews.pm	118 B	-r--r--r--
Split.pm	2.28 KB	-r--r--r--
ssh.pm	122 B	-r--r--r--
telnet.pm	95 B	-r--r--r--
tn3270.pm	95 B	-r--r--r--
URL.pm	5.4 KB	-r--r--r--
urn.pm	1.91 KB	-r--r--r--
_userpass.pm	977 B	-r--r--r--
WithBase.pm	3.74 KB	-r--r--r--

Code Editor : Split.pm

package URI::Split;

use strict;

use vars qw(@ISA @EXPORT_OK);
require Exporter;
@ISA = qw(Exporter);
@EXPORT_OK = qw(uri_split uri_join);

use URI::Escape ();

sub uri_split {
     return $_[0] =~ m,(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:\?([^#]*))?(?:#(.*))?,;
}

sub uri_join {
    my($scheme, $auth, $path, $query, $frag) = @_;
    my $uri = defined($scheme) ? "$scheme:" : "";
    $path = "" unless defined $path;
    if (defined $auth) {
	$auth =~ s,([/?\#]),$URI::Escape::escapes{$1},g;
	$uri .= "//$auth";
	$path = "/$path" if length($path) && $path !~ m,^/,;
    }
    elsif ($path =~ m,^//,) {
	$uri .= "//";  # XXX force empty auth
    }
    unless (length $uri) {
	$path =~ s,(:),$URI::Escape::escapes{$1}, while $path =~ m,^[^:/?\#]+:,;
    }
    $path =~ s,([?\#]),$URI::Escape::escapes{$1},g;
    $uri .= $path;
    if (defined $query) {
	$query =~ s,(\#),$URI::Escape::escapes{$1},g;
	$uri .= "?$query";
    }
    $uri .= "#$frag" if defined $frag;
    $uri;
}

__END__

=head1 NAME

URI::Split - Parse and compose URI strings

=head1 SYNOPSIS

use URI::Split qw(uri_split uri_join);
 ($scheme, $auth, $path, $query, $frag) = uri_split($uri);
 $uri = uri_join($scheme, $auth, $path, $query, $frag);

=head1 DESCRIPTION

Provides functions to parse and compose URI
strings.  The following functions are provided:

=over

=item ($scheme, $auth, $path, $query, $frag) = uri_split($uri)

Breaks up a URI string into its component
parts.  An C<undef> value is returned for those parts that are not
present.  The $path part is always present (but can be the empty
string) and is thus never returned as C<undef>.

No sensible value is returned if this function is called in a scalar
context.

=item $uri = uri_join($scheme, $auth, $path, $query, $frag)

Puts together a URI string from its parts.
Missing parts are signaled by passing C<undef> for the corresponding
argument.

Minimal escaping is applied to parts that contain reserved chars
that would confuse a parser.  For instance, any occurrence of '?' or '#'
in $path is always escaped, as it would otherwise be parsed back
as a query or fragment.

=back

=head1 SEE ALSO

L<URI>, L<URI::Escape>

=head1 COPYRIGHT

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut

${this.title}

Code Editor : Split.pm